一个免费无限爬楼脚本思路 免费奉献

李逍遥

首先随便建个NPC进入塔

地图以D515祖玛教主大厅为例子

[@main]
<进入爬楼/@jrpt1>    \ \



[@jrpt1]
#IF
#ACT
MOV U10 0
MOV U11 10000
AddMirrorMap D515 <$USERNAME>通天1层塔 通天1层塔 60 3 D515 N80 1
MONGENEX <$USERNAME>通天1层塔 23 21 稻草人·(普通) 60 1 249
DELAYGOTO 200 @进入1


[@进入1]
#IF
#ACT
inc U10 1
CalcPercent 10000 <$STR(U10)> N20
inc U11 <$STR(N20)>
ChangeMonAbility <$USERNAME>通天1层塔 * 0 = <$STR(U11)> 1
ChangeMonAbility <$USERNAME>通天1层塔 * 1 = <$STR(U11)> 1
ChangeMonAbility <$USERNAME>通天1层塔 * 30 + 0
RecalcMonAbility <$USERNAME>通天1层塔 *
ChangeMapMonNameEx <$USERNAME>通天1层塔 0 0 0 稻草人·(普通) 通天塔·boss1
map <$USERNAME>通天1层塔

然后QF[@KillMon]触发杀怪无限进入下层塔

[@KillMon]
#IF
ISONMAP <$USERNAME>通天<$STR(U10)>层塔
CheckContainsText <$KILLMONNAME><$STR(U10)> <$KILLMONNAME>
#ACT
inc U10 1
CalcPercent 10000 <$STR(U10)> N20
inc U11 <$STR(N20)>
AddMirrorMap D515 <$USERNAME>通天<$STR(U10)>层塔 通天<$STR(U10)>层塔 60 3 D515 N80 1
MONGENEX <$USERNAME>通天<$STR(U10)>层塔 23 21 稻草人·(普通) 60 1 249
SHOWPROGRESSBARDLG 3 @进入2 正在进入下层,进度%d%... 0

[@进入2]
#IF
#ACT
ChangeMonAbility <$USERNAME>通天<$STR(U10)>层塔 * 0 = <$STR(U11)> 1
ChangeMonAbility <$USERNAME>通天<$STR(U10)>层塔 * 1 = <$STR(U11)> 1
ChangeMonAbility <$USERNAME>通天<$STR(U10)>层塔 * 30 + 0
RecalcMonAbility <$USERNAME>通天<$STR(U10)>层塔 *
ChangeMapMonNameEx <$USERNAME>通天<$STR(U10)>层塔 0 0 0 稻草人·(普通) 通天塔·boss<$STR(U10)>
map <$USERNAME>通天<$STR(U10)>层塔

每层怪物血量稍微递增一点，本人亲测第一层1W血，打到370层才700W血量不到。奖励啥的，自行添加。

然后不定因素原因，导致个人镜像删除，或者不删除，可以这样：
QF：
[@PlayOffLine]  ;人物大退触发
#IF
#ACT
DelMirrorMap <$USERNAME>通天1层塔
DelMirrorMap <$USERNAME>通天<$STR(U10)>层塔

[@PlayReconnection]  ;人物小退触发
#IF
#ACT
DelMirrorMap <$USERNAME>通天1层塔
DelMirrorMap <$USERNAME>通天<$STR(U10)>层塔

;盟重回城石
[@StdModeFunc22]
#IF
#ACT
DelMirrorMap <$USERNAME>通天1层塔
DelMirrorMap <$USERNAME>通天<$STR(U10)>层塔